home *** CD-ROM | disk | FTP | other *** search
/ IRIX 6.4 Applications 1997 August / SGI IRIX 6.4 Applications 1997 August.iso / dist / mmailp.idb / usr / lib / Zmail / bin / showexternal.z / showexternal
Encoding:
Text File  |  1997-01-22  |  6.1 KB  |  247 lines
  1. #!/bin/csh -fb
  2. # (The "-fb" might need to be changed to "-f" on some systems)
  3. #
  4. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  5. # 
  6. # Permission to use, copy, modify, and distribute this material 
  7. # for any purpose and without fee is hereby granted, provided 
  8. # that the above copyright notice and this permission notice 
  9. # appear in all copies, and that the name of Bellcore not be 
  10. # used in advertising or publicity pertaining to this 
  11. # material without the specific, prior written permission 
  12. # of an authorized representative of Bellcore.  BELLCORE 
  13. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  14. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  15. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  16. # 
  17.  
  18. onintr cleanup
  19. if (! $?METAMAIL_TMPDIR) then
  20.     set METAMAIL_TMPDIR=/tmp
  21. endif
  22. if (! $?FTP) then
  23.     set FTP=ftp
  24. endif
  25.  
  26. if ($#argv <3) then
  27.     echo "Usage: showexternal body-file access-type name [site [directory [mode [server]]]]"
  28.     exit -1
  29. endif
  30. set bodyfile=$1
  31. set atype=`echo $2 | tr ABCDEFGHIJKLMNOPQRSTUVWXYZ abcdefghijklmnopqrstuvwxyz`
  32. set name=$3
  33. if ($#argv > 3) then
  34.     set site=$4
  35. else 
  36.     set site=""
  37. endif
  38. if ($#argv > 4) then
  39.     set dir=$5
  40. else
  41.     set dir=""
  42. endif
  43. if ($#argv > 5) then
  44.     set mode=$6
  45. else
  46.     set mode=""
  47. endif
  48. if ($#argv > 6) then
  49.     set server=$7
  50. else
  51.     set server=""
  52. endif
  53.  
  54. if ("$server" == "" && $atype == "mail-server") then
  55. # Backward compatibility with some broken stuff
  56.     set server=${name}@${site}
  57.     echo WARNING -- old style mailserver syntax, using server $server
  58. endif
  59.  
  60. set ctype="`grep -i content-type: $bodyfile | sed -e 's/............: //'`"
  61. if ("$ctype" == "") set ctype="text/plain"
  62. set cenc=`grep -i content-transfer-encoding: $bodyfile | sed -e 's/.........................: //'`
  63. set username=""
  64. set pass=""
  65. set TMPDIR=${METAMAIL_TMPDIR}/Xternal.$$
  66. mkdir $TMPDIR
  67. pushd $TMPDIR
  68. set NEWNAME="mm.ext.$$"
  69. set NEEDSCONFIRMATION=1
  70. switch ("$atype")
  71.     case anon-ftp:
  72.     echo "This mail message contains a POINTER (reference) to data that is "
  73.     echo not included in the message itself.  Rather, the data can be retrieved 
  74.     echo automatically using  anonymous FTP to a site on the network.
  75.     breaksw
  76.     case ftp:
  77.     echo "This mail message contains a POINTER (reference) to data that is "
  78.     echo not included in the message itself.  Rather, the data can be retrieved 
  79.     echo automatically using  the FTP protocol to a site on the network.
  80.     breaksw
  81.     case mail-server:  
  82.     cat > ${METAMAIL_TMPDIR}/X.junk.$$ <<!
  83. This mail message contains a POINTER (reference) to data that is 
  84. not included in the message itself.  Rather, the data can be retrieved 
  85. by sending a special mail message to a mail server on the network.
  86. However, doing this automatically is slightly dangerous, because  someone
  87. might be using this mechanism to cause YOU to send obnoxious mail.
  88. For that reason, the mail message that WOULD be sent is being shown to you
  89. first for your approval.
  90.  
  91. This is the message that will be sent if you choose to go ahead and
  92. retreive the external data:
  93.  
  94. Subject: Automated Mail Server Request
  95. To: ${server}
  96.  
  97. !
  98.     sed -e 1,/^\$/d < $bodyfile >> ${METAMAIL_TMPDIR}/X.junk.$$
  99.     more ${METAMAIL_TMPDIR}/X.junk.$$
  100.     rm ${METAMAIL_TMPDIR}/X.junk.$$
  101.     breaksw
  102.     default:
  103.     # IGNORE ALL THE OTHERS -- AUTOMATIC FOR LOCAL-FILE, AFS.
  104.     set NEEDSCONFIRMATION=0
  105. endsw
  106.  
  107. if ($NEEDSCONFIRMATION) then
  108.     echo ""
  109.     echo -n "Do you want to proceed with retrieving the external data [y] ? "
  110.     set ANS=$<
  111.     if ("$ANS" =~ n* ||  "$ANS" =~ N* ) then
  112.         cd ${METAMAIL_TMPDIR}
  113.         rm -rf $TMPDIR
  114.         exit 0
  115.     endif
  116. endif
  117.  
  118. switch ("$atype")
  119.     case anon-ftp:
  120.     set username=anonymous
  121.     set pass=`whoami`@`hostname`
  122.     # DROP THROUGH
  123.     case ftp:
  124.     if ("$site" == "") then
  125.         echo -n "Site for ftp access: "
  126.         set site=$<
  127.     endif
  128.     if ("$username" == "") then
  129.         echo -n "User name at site ${site}: "
  130.         set username=$<
  131.     endif
  132.     if ("$pass" == "") then
  133.         echo -n "Password for user $username at site ${site}: "
  134.         stty -echo
  135.         set pass=$<
  136.         stty echo
  137.         echo ""
  138.     endif
  139.     if ("$dir" == "") then
  140.         set DIRCMD=""
  141.     else
  142.         set DIRCMD="cd $dir"
  143.     endif
  144.     if ("$mode" == "") then
  145.         set MODECMD=""
  146.     else
  147.         set MODECMD="type $mode"
  148.     endif
  149.     echo OBTAINING MESSAGE BODY USING FTP
  150.     echo SITE: $site USER $username
  151.     $FTP -n <<!
  152. open $site
  153. user $username $pass
  154. $DIRCMD
  155. $MODECMD
  156. get $name $NEWNAME
  157. quit
  158. !
  159.     if (! -e $NEWNAME) then
  160.         echo FTP failed.
  161.         cd ${METAMAIL_TMPDIR}
  162.         rm -rf $TMPDIR
  163.         exit -1
  164.     endif
  165.     breaksw
  166.     case afs:
  167.     case local-file:
  168.     if (! -e $name) then
  169.         echo local file not found
  170.         cd ${METAMAIL_TMPDIR}
  171.         rm -rf $TMPDIR
  172.         exit -1
  173.     endif
  174.         set NEWNAME=$name
  175.     echo GETTING BODY FROM FILE NAMED: $NEWNAME
  176.     breaksw
  177.     case mail-server:  # A very special case
  178.     if ("$bodyfile" == "") then
  179.         echo mail-server access-type requires a body file
  180.         cd ${METAMAIL_TMPDIR}
  181.         rm -rf $TMPDIR
  182.         exit -1
  183.     endif
  184.     echo Subject: Automated Mail Server Request > $NEWNAME
  185.     echo To: ${server} >> $NEWNAME
  186.     echo "" >> $NEWNAME
  187.     sed -e 1,/^\$/d < $bodyfile >> $NEWNAME
  188.     echo "" >> $NEWNAME
  189.     /usr/lib/sendmail -t  < $NEWNAME
  190.     if ($status) then
  191.         echo sendmail failed
  192.         cd ${METAMAIL_TMPDIR}
  193.         rm -rf $TMPDIR
  194.         exit -1
  195.     endif
  196.     cd ${METAMAIL_TMPDIR}
  197.     rm -rf $TMPDIR
  198.     echo Your $ctype data has been requested from a mail server.
  199.     exit 0
  200.     default:
  201.     echo UNRECOGNIZED ACCESS-TYPE
  202.     cd ${METAMAIL_TMPDIR}
  203.     rm -rf $TMPDIR
  204.     exit -1
  205. endsw
  206. if ($cenc == base64) then
  207.     mimencode -u -b < $NEWNAME > OUT
  208.     mv OUT $NEWNAME
  209. else if ($cenc == quoted-printable) then
  210.     mimencode -u -q < $NEWNAME > OUT
  211.     mv OUT $NEWNAME
  212. endif
  213.  
  214. popd
  215. if ($atype == "local-file") then
  216.     metamail -p  -b -c "$ctype" $NEWNAME
  217. else
  218.     metamail -p -b -c "$ctype" $TMPDIR/$NEWNAME
  219. endif
  220.  
  221. if ($status) then
  222.     echo metamail failed
  223.     cd ${METAMAIL_TMPDIR}
  224.     rm -rf $TMPDIR
  225.     exit -1
  226. endif
  227.  
  228. if ($NEWNAME != $name) then
  229.     echo ""
  230.     echo The data just displayed is stored in the file $TMPDIR/$NEWNAME
  231.     echo "Do you want to delete it?"
  232.     rm -i $TMPDIR/$NEWNAME
  233. endif
  234.  
  235. if (! -e ${TMPDIR}/${NEWNAME}) then
  236.     cd ${METAMAIL_TMPDIR}
  237.     rmdir $TMPDIR
  238. endif
  239. exit 0
  240.  
  241. cleanup:
  242. cd ${METAMAIL_TMPDIR}
  243. if (-e $TMPDIR) then    
  244.     rmdir $TMPDIR
  245. endif
  246. exit -1
  247.